package MT::Plugin::SKR::SpeedySystemMenu;
# SpeedySystemMenu - Add sub menus onto drop down menu of system overview.
#       Copyright (c) 2010 SKYARC System Co.,Ltd.
#       http://www.skyarc.co.jp/engineerblog/entry/speedysystemmenu.html

use strict;
use MT 5;

use vars qw( $MYNAME $VERSION );
$MYNAME = 'SpeedySystemMenu';
$VERSION = '0.01';

use base qw( MT::Plugin );
my $plugin = __PACKAGE__->new({
        id => $MYNAME,
        key => $MYNAME,
        name => $MYNAME,
        version => $VERSION,
        author_name => 'SKYARC System Co.,Ltd.',
        author_link => 'http://www.skyarc.co.jp/',
        doc_link => 'http://www.skyarc.co.jp/engineerblog/entry/speedysystemmenu.html',
        description => <<HTMLHEREDOC,
<__trans phrase="Add sub menus onto drop down menu of system overview.">
HTMLHEREDOC
});
MT->add_plugin( $plugin );

sub instance { $plugin; }

### Registry
sub init_registry {
    my $plugin = shift;
    $plugin->registry({
        callbacks => {
            'MT::App::CMS::template_source.header' => \&_hdlr_src_header,
            'MT::App::CMS::template_param' => \&_hdlr_param,
        },
    });
}

### template_source.header
sub _hdlr_src_header {
    my ($cb, $app, $tmpl) = @_;


    ### <style> addition
    my $old = quotemeta (<<'HTMLHEREDOC');
<mt:var name="html_head">
HTMLHEREDOC
    my $new = <<'HTMLHEREDOC';
<mt:setvarblock name="html_head" prepend="1">
<style>
#speedy_sys_menus {
    margin-left: 15px;
    font-size: 10pt;
}

#speedy_sys_menus ul.speedy_sys_submenus {
    margin-left: 30px;
}

#speedy_sys_menus ul.speedy_sys_submenus li {
    display: inline;
}

#speedy_sys_menus ul.speedy_sys_submenus li a {
    display: inline;
}
</style>
</mt:setvarblock>
HTMLHEREDOC
    $$tmpl =~ s/($old)/$new$1/;

    ### speedy_sys_menus addition
    $old = quotemeta (<<'HTMLHEREDOC');
                                <a href="<$mt:var name="mt_url">?blog_id=0&amp;<$mt:var name="return_args" escape="html"$>"><__trans phrase="System Overview"></a>
HTMLHEREDOC
    $new = <<'HTMLHEREDOC';
<TMPL_IF NAME=SPEEDY_SYS_MENUS><ul id="speedy_sys_menus"><TMPL_LOOP NAME=SPEEDY_SYS_MENUS>
  <li><TMPL_VAR NAME=LABEL>
    <TMPL_IF NAME=SUB_MENUS><ul class="speedy_sys_submenus"><TMPL_LOOP NAME=SUB_MENUS>
      <li><a href="<$mt:var script_url$>?<TMPL_VAR NAME=QUERY>"><TMPL_VAR NAME=LABEL ESCAPE=HTML></a></li>
    </TMPL_LOOP></ul></TMPL_IF>
  </li>
</TMPL_LOOP></ul></TMPL_IF>
HTMLHEREDOC
    $$tmpl =~ s/($old)/$1$new/;
}

### template_param.*
sub _hdlr_param {
    my ($cb, $app, $param, $tmpl) = @_;


    my @speedy_sys_menus;
    my $menus = $app->registry ('menus');
    my @topids = sort { $menus->{$a}->{order} <=> $menus->{$b}->{order} } grep { !/:/ } keys %$menus;
    foreach my $topid (@topids) {
        my @submenus;
        my $top_menu = $menus->{$topid};
        my @subids = sort { $menus->{$a}->{order} <=> $menus->{$b}->{order} } grep { /^$topid:/ } keys %$menus;
        foreach my $subid (@subids) {
            my $sub_menu = $menus->{$subid};
            my $has_system = 0;
            if (!exists $sub_menu->{view} || (exists $sub_menu->{display} && !$sub_menu->{display})) {
                # do nothing
            }
            elsif (ref $sub_menu->{view} eq 'CODE') {
                map { $has_system |= /^system$/ } @{$sub_menu->{view}->()};
            }
            elsif (ref $sub_menu->{view} eq 'ARRAY') {
                map { $has_system |= /^system$/ } @{$sub_menu->{view}};
            }
            else {
                $has_system |= $sub_menu->{view} =~ /^system$/;
            }
            next if !$has_system;
            my %query = (
                __mode => $sub_menu->{mode},
                $sub_menu->{args}
                    ? %{$sub_menu->{args}}
                    : (),
            );
            $sub_menu->{query} = join '&', map { $_. '='. $query{$_} } keys %query;
            push @submenus, $sub_menu;
        }
        if (@submenus) {
            $top_menu->{sub_menus} = \@submenus;
            push @speedy_sys_menus, $top_menu;
        }
    }
    $param->{speedy_sys_menus} = \@speedy_sys_menus if @speedy_sys_menus;
}

1;